Misurare la temperatura e l’umidità con Arduino usando il sensore DHT22

Misurare la temperatura e l’umidità con Arduino usando il sensore DHT22

Ho già trattato questo sensore esprimendo il mio parere in un articolo ad hoc al quale ti rimando. Ho già espresso la mia preferenza per questo sensore rispetto al DHT11 e di fatto lo consiglio anche a voi. E’ vero che costa poco di più rispetto al DHT11 ma ne guadagnerete in precisione e range di valori misurati.

Collegamento con Arduino

Schema di collegamento

Come puoi vedere lo schema qui sopra, il collegamento è molto semplice.

  1. Il pin 1 (GND) deve essere collegato a GND di Arduino
  2. Il pin 2 (Dati) lo colleghiamo al pin 3 di Arduino inserendo però una resistenza da 220 Kohm che collega il pin dati al pin Vcc
  3. Il pin 3 non è collegato a niente (se presente)
  4. Il pin 4 (Vcc) deve essere collegato a 5V di Arduino

Sketch

Anche lo sketch, così come lo schema di collegamento, è semplice.

Innanzitutto vi occorrerà la libreria DHT di Adafruit scaricabile da qui.

Installando questa libreria avrete a disposizione alcuni esempi come DHTtester che vi riporto qui sotto. Si può usare anche per il sensore DHT11.

// Example testing sketch for various DHT humidity/temperature sensors
// Written by ladyada, public domain

// REQUIRES the following Arduino libraries:
// - DHT Sensor Library: https://github.com/adafruit/DHT-sensor-library
// - Adafruit Unified Sensor Lib: https://github.com/adafruit/Adafruit_Sensor

#include "DHT.h"

#define DHTPIN 3     // Digital pin connected to the DHT sensor
// Feather HUZZAH ESP8266 note: use pins 3, 4, 5, 12, 13 or 14 --
// Pin 15 can work but DHT must be disconnected during program upload.

// Uncomment whatever type you're using!
//#define DHTTYPE DHT11   // DHT 11
#define DHTTYPE DHT22   // DHT 22  (AM2302), AM2321
//#define DHTTYPE DHT21   // DHT 21 (AM2301)

// Connect pin 1 (on the left) of the sensor to +5V
// NOTE: If using a board with 3.3V logic like an Arduino Due connect pin 1
// to 3.3V instead of 5V!
// Connect pin 2 of the sensor to whatever your DHTPIN is
// Connect pin 4 (on the right) of the sensor to GROUND
// Connect a 10K resistor from pin 2 (data) to pin 1 (power) of the sensor

// Initialize DHT sensor.
// Note that older versions of this library took an optional third parameter to
// tweak the timings for faster processors.  This parameter is no longer needed
// as the current DHT reading algorithm adjusts itself to work on faster procs.
DHT dht(DHTPIN, DHTTYPE);

void setup() {
  Serial.begin(9600);
  Serial.println(F("DHTxx test!"));

  dht.begin();
}

void loop() {
  // Wait a few seconds between measurements.
  delay(2000);

  // Reading temperature or humidity takes about 250 milliseconds!
  // Sensor readings may also be up to 2 seconds 'old' (its a very slow sensor)
  float h = dht.readHumidity();
  // Read temperature as Celsius (the default)
  float t = dht.readTemperature();
  // Read temperature as Fahrenheit (isFahrenheit = true)
  float f = dht.readTemperature(true);

  // Check if any reads failed and exit early (to try again).
  if (isnan(h) || isnan(t) || isnan(f)) {
    Serial.println(F("Failed to read from DHT sensor!"));
    return;
  }

  // Compute heat index in Fahrenheit (the default)
  float hif = dht.computeHeatIndex(f, h);
  // Compute heat index in Celsius (isFahreheit = false)
  float hic = dht.computeHeatIndex(t, h, false);

  Serial.print(F("Humidity: "));
  Serial.print(h);
  Serial.print(F("%  Temperature: "));
  Serial.print(t);
  Serial.print(F("°C "));
  Serial.print(f);
  Serial.print(F("°F  Heat index: "));
  Serial.print(hic);
  Serial.print(F("°C "));
  Serial.print(hif);
  Serial.println(F("°F"));
}

Questo esempio rileverà la temperatura e l’umidità ogni 2 secondi.

Acquista il sensore DHT22

Qualche manuale dedicato ad Arduino

Share This:

Lascia un commento

Il tuo indirizzo email non sarà pubblicato. I campi obbligatori sono contrassegnati *

Questo sito usa Akismet per ridurre lo spam. Scopri come i tuoi dati vengono elaborati.